feat(Cmake/Build): Use interface targets for inheriting flags and definitions (#2255)

Co-authored-by: Naios Naios@users.noreply.github.com

src/cmake/compiler/msvc/settings.cmake

@@ -1,3 +1,8 @@
+#
+# Copyright (C) 2016+     AzerothCore <www.azerothcore.org>, released under GNU AGPL3 v3 license: https://github.com/azerothcore/azerothcore-wotlk/blob/master/LICENSE-AGPL3
+# Copyright (C) 2008-2019 TrinityCore <https://www.trinitycore.org/>
+#
+
 # set up output paths for executable binaries (.exe-files, and .dll-files on DLL-capable platforms)
 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
 
@@ -5,14 +10,25 @@ set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
 #set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
 #set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
 
+# CMake sets warning flags by default, however we manage it manually
+# for different core and dependency targets
+string(REGEX REPLACE "/W[0-4] " "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
+# Search twice, once for space after /W argument,
+# once for end of line as CMake regex has no \b
+string(REGEX REPLACE "/W[0-4]$" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
+string(REGEX REPLACE "/W[0-4] " "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
+string(REGEX REPLACE "/W[0-4]$" "" CMAKE_C_FLAGS "${CMAKE_C_FLAGS}")
+
 if(PLATFORM EQUAL 64)
   # This definition is necessary to work around a bug with Intellisense described
   # here: http://tinyurl.com/2cb428.  Syntax highlighting is important for proper
   # debugger functionality.
-  add_definitions("-D_WIN64")
+  target_compile_definitions(acore-compile-option-interface
+    INTERFACE
+      -D_WIN64)
   message(STATUS "MSVC: 64-bit platform, enforced -D_WIN64 parameter")
 
-  #Enable extended object support for debug compiles on X64 (not required on X86)
+  # Enable extended object support for debug compiles on X64 (not required on X86)
   set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /bigobj")
   message(STATUS "MSVC: Enabled extended object-support for debug-compiles")
 else()
@@ -20,40 +36,67 @@ else()
   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /LARGEADDRESSAWARE")
   message(STATUS "MSVC: Enabled large address awareness")
 
-  add_definitions(/arch:SSE2)
+  target_compile_options(acore-compile-option-interface
+    INTERFACE
+      /arch:SSE2)
   message(STATUS "MSVC: Enabled SSE2 support")
 endif()
 
-message(STATUS "MSVC: Enabled С++17 support")
-set(CMAKE_CXX_STANDARD 17)
-
 # Set build-directive (used in core to tell which buildtype we used)
-add_definitions(-D_BUILD_DIRECTIVE=\\"$(ConfigurationName)\\")
+# msbuild/devenv don't set CMAKE_MAKE_PROGRAM, you can choose build type from a dropdown after generating projects
+if("${CMAKE_MAKE_PROGRAM}" MATCHES "MSBuild")
+  target_compile_definitions(acore-compile-option-interface
+    INTERFACE
+      -D_BUILD_DIRECTIVE="$(ConfigurationName)")
+else()
+  # while all make-like generators do (nmake, ninja)
+  target_compile_definitions(acore-compile-option-interface
+    INTERFACE
+      -D_BUILD_DIRECTIVE="${CMAKE_BUILD_TYPE}")
+endif()
 
 # multithreaded compiling on VS
-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /MP")
+target_compile_options(acore-compile-option-interface
+  INTERFACE
+    /MP)
 
 # Define _CRT_SECURE_CPP_OVERLOAD_STANDARD_NAMES - eliminates the warning by changing the strcpy call to strcpy_s, which prevents buffer overruns
-add_definitions(-D_CRT_SECURE_CPP_OVERLOAD_STANDARD_NAMES)
+target_compile_definitions(acore-compile-option-interface
+  INTERFACE
+    -D_CRT_SECURE_CPP_OVERLOAD_STANDARD_NAMES)
 message(STATUS "MSVC: Overloaded standard names")
 
 # Ignore warnings about older, less secure functions
-add_definitions(-D_CRT_SECURE_NO_WARNINGS)
+target_compile_definitions(acore-compile-option-interface
+  INTERFACE
+    -D_CRT_SECURE_NO_WARNINGS)
 message(STATUS "MSVC: Disabled NON-SECURE warnings")
 
-#Ignore warnings about POSIX deprecation
-add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
+# Ignore warnings about POSIX deprecation
+target_compile_definitions(acore-compile-option-interface
+  INTERFACE
+    -D_CRT_NONSTDC_NO_WARNINGS)
 message(STATUS "MSVC: Disabled POSIX warnings")
 
-#Ignore warnings about INTMAX_MAX
-add_definitions(-D__STDC_LIMIT_MACROS)
+# Ignore warnings about INTMAX_MAX
+target_compile_definitions(acore-compile-option-interface
+  INTERFACE
+    -D__STDC_LIMIT_MACROS)
 message(STATUS "MSVC: Disabled INTMAX_MAX warnings")
 
 # disable warnings in Visual Studio 8 and above if not wanted
 if(NOT WITH_WARNINGS)
   if(MSVC AND NOT CMAKE_GENERATOR MATCHES "Visual Studio 7")
-    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /wd4996 /wd4355 /wd4244 /wd4985 /wd4267 /wd4619")
-    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4996 /wd4355 /wd4244 /wd4985 /wd4267 /wd4619")
+  target_compile_options(acore-warning-interface
+    INTERFACE
+      /wd4996
+      /wd4355
+      /wd4244
+      /wd4985
+      /wd4267
+      /wd4619
+      # /wd4512
+      )    
     message(STATUS "MSVC: Disabled generic compiletime warnings")
   endif()
 endif()
@@ -67,4 +110,7 @@ set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Zm500")
 # Enable and treat as errors the following warnings to easily detect virtual function signature failures:
 # 'function' : member function does not override any base class virtual member function
 # 'virtual_function' : no override available for virtual member function from base 'class'; function is hidden
-set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /we4263 /we4264")
+target_compile_options(acore-warning-interface
+  INTERFACE
+    /we4263
+    /we4264)