feat(Cmake/Build): Use interface targets for inheriting flags and definitions (#2255)

Co-authored-by: Naios Naios@users.noreply.github.com

src/cmake/compiler/mingw/settings.cmake

@@ -1,27 +1,46 @@
+#
+# Copyright (C) 2016+     AzerothCore <www.azerothcore.org>, released under GNU AGPL3 v3 license: https://github.com/azerothcore/azerothcore-wotlk/blob/master/LICENSE-AGPL3
+# Copyright (C) 2008-2019 TrinityCore <https://www.trinitycore.org/>
+#
+
 # set up output paths for executable binaries (.exe-files, and .dll-files on DLL-capable platforms)
 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)
 
 # Set build-directive (used in core to tell which buildtype we used)
-add_definitions(-D_BUILD_DIRECTIVE=\\"${CMAKE_BUILD_TYPE}\\")
+target_compile_definitions(acore-compile-option-interface
+  INTERFACE
+    -D_BUILD_DIRECTIVE="${CMAKE_BUILD_TYPE}")
 
 if(PLATFORM EQUAL 32)
   # Required on 32-bit systems to enable SSE2 (standard on x64)
-  set(SSE_FLAGS "-msse2 -mfpmath=sse")
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${SSE_FLAGS}")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${SSE_FLAGS}")
+  target_compile_options(acore-compile-option-interface
+    INTERFACE
+      -msse2
+      -mfpmath=sse)
 endif()
-add_definitions(-DHAVE_SSE2 -D__SSE2__)
+
+target_compile_definitions(acore-compile-option-interface
+  INTERFACE
+    -DHAVE_SSE2
+    -D__SSE2__)
 message(STATUS "GCC: SFMT enabled, SSE2 flags forced")
 
-if( WITH_WARNINGS )
-  set(WARNING_FLAGS "-W -Wall -Wextra -Winit-self -Winvalid-pch -Wfatal-errors")
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${WARNING_FLAGS}")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${WARNING_FLAGS} -Woverloaded-virtual")
+if(WITH_WARNINGS)
+  target_compile_options(acore-warning-interface
+  INTERFACE
+    -W
+    -Wall
+    -Wextra
+    -Winit-self
+    -Winvalid-pch
+    -Wfatal-errors
+    -Woverloaded-virtual)
   message(STATUS "GCC: All warnings enabled")
 endif()
 
-if( WITH_COREDEBUG )
-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g3")
-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g3")
+if(WITH_COREDEBUG)
+  target_compile_options(acore-compile-option-interface
+    INTERFACE
+      -g3)
   message(STATUS "GCC: Debug-flags set (-g3)")
 endif()